home *** CD-ROM | disk | FTP | other *** search
- 10 GOTO 100
- 20 CLEARW 2
- 22 LINEF 100,14,539,14:LINEF 539,14,539,34:LINEF 539,34,100,34
- 24 LINEF 100,34,100,14:COLOR 1,2,1:FILL 319,15
- 26 GOTOXY 20,2:? " CAREER SATISFACTION & EVALUATION "
- 28 RETURN
- 30 FOR NDX=1 TO MAX:READ A$
- 32 GOTOXY 5,10:? BLANK$:GOTOXY 5,10:? A$
- 34 GOTOXY 10,15:INPUT " YOUR CHOICE ?",D$:A=ASC(LEFT$(D$,1))
- 36 IF A<49 OR A>51 THEN 32
- 38 A=A-48:ON A GOSUB 40,50,60
- 39 NEXT NDX:RETURN
- 40 ANS(NDX)=0:RETURN
- 50 ANS(NDX)=5:RETURN
- 60 ANS(NDX)=10:RETURN
- 70 FOR NDX=1 TO MAX:ANS(TOT)=ANS(TOT)+ANS(NDX):NEXT NDX:RETURN
- 100 FULLW 2:CLEARW 2
- 110 DIM ANS(15):BLANK$=STRING$(130," ")
- 120 B$=" 1> NOT TRUE 2> SOMEWHAT TRUE 3> ABSOLUTELY TRUE"
- 130 FOR I=1 TO 15:ANS(I)=0:NEXT I:IF AGN THEN 260
- 140 GOSUB 20
- 150 GOTOXY 11,5:? "Your answers to the statements in this quiz will help"
- 160 ? TAB(13);"you determine whether your current career is the right"
- 170 ? TAB(13);"one for you."
- 180 ? :? TAB(13);"This quiz evaluates five distinct categories concerning"
- 190 ? TAB(13);"your current career and assigns a numerical value to"
- 200 ? TAB(13);"each. When you have finished the quiz, the categories"
- 210 ? TAB(13);"will be displayed along with your score in each. An"
- 220 ? TAB(13);"evaluation of your suitability for your current career"
- 230 ? TAB(13);"will also be shown."
- 240 COLOR 2,2,1
- 250 ? :? TAB(18);"Press <RETURN> when ready to take quiz.....";:INPUT A$
- 260 COLOR 1,2,1
- 270 CLEARW 2:GOSUB 20
- 280 GOTOXY 11,6:? "SELECT THE ANSWER THAT IS MOST APPROPRIATE."
- 290 GOTOXY 1,13:? B$
- 300 MAX=5:GOSUB 30:TOT=10:GOSUB 70
- 310 MAX=6:GOSUB 30:TOT=11:GOSUB 70
- 320 MAX=7:GOSUB 30:TOT=12:GOSUB 70
- 330 MAX=5:GOSUB 30:TOT=13:GOSUB 70
- 340 MAX=5:GOSUB 30:TOT=14:GOSUB 70
- 350 FOR NDX=10 TO 14:ANS(15)=ANS(15)+ANS(NDX):NEXT NDX
- 360 CLEARW 2
- 370 LINEF 100,14,539,14:LINEF 539,14,539,34:LINEF 539,34,100,34
- 380 LINEF 100,34,100,14:COLOR 1,3,1:FILL 319,15
- 390 GOTOXY 27,2:? " EVALUATION PROFILE "
- 400 SUIT=0:IF ANS(10)>30 THEN SUIT=SUIT+2
- 410 IF ANS(11)>=35 THEN SUIT=SUIT+2
- 420 IF ANS(12)>=40 THEN SUIT=SUIT+2
- 430 IF ANS(13)>=30 THEN SUIT=SUIT+2
- 435 IF ANS(14)>=30 THEN SUIT=SUIT+2
- 440 ? :? :? TAB(26);"Category";TAB(50);"Points"
- 450 ? TAB(25);"-------------------------------"
- 460 ? TAB(25);"FINANCIAL";TAB(52);ANS(10)
- 470 ? TAB(25);"PSYCHOLOGICAL";TAB(52);ANS(11)
- 480 ? TAB(25);"PERSONALITY";TAB(52);ANS(12)
- 490 ? TAB(25);"COMPATIBILITY";TAB(52);ANS(13)
- 500 ? TAB(25);"POTENTIAL";TAB(52);ANS(14)
- 510 ? TAB(25);"-------------------------------"
- 520 ? TAB(26);"Composite Total";TAB(51);ANS(15)
- 530 ? :? " ON A SCALE OF 1 TO 10, YOUR JOB SUITABILITY RATES";SUIT
- 540 IF SUIT<=2 THEN ? " YOU ARE DEFINITELY IN THE WRONG JOB."
- 550 IF SUIT=4 THEN ? " YOU PROBABLY SHOULD CHANGE CAREERS."
- 560 IF SUIT=6 THEN ? " YOU MAY OR MAY NOT BE SUITED FOR YOUR CAREER."
- 570 IF SUIT=8 THEN ? " YOU ARE FAIRLY WELL SUITED FOR YOUR CAREER."
- 580 IF SUIT=10 THEN ? " YOU ARE VERY WELL SUITED FOR YOUR CAREER."
- 590 INPUT " Press <RETURN> to do again. ",A$
- 600 CLEAR:AGN=1:RESTORE:GOTO 10
- 1000 DATA I am making a satisfactory amount of money.
- 1010 DATA My financial situation probably will improve in the coming years.
- 1020 DATA In my field--I will continue to be paid in an amount consistent with my abilities.
- 1030 DATA I can earn more money if I work harder and/or more creatively.
- 1040 DATA The income potential in my field continues to look good.
- 1050 DATA I like to think about my work--even when I'm not on the job.
- 1060 DATA I often find my work fun.
- 1070 DATA My work is important to society.
- 1080 DATA I look forward to going to work.
- 1090 DATA I feel that I have an opportunity to grow personally because of my career.
- 1100 DATA My work helps enhance my family life and my life as a whole.
- 1110 DATA I am adequately able to set my own owrk pace and direction on the job.
- 1120 DATA At work--I am most content when I can try out my own ideas--and that happens often.
- 1130 DATA There is great variety in my job.
- 1140 DATA My job is so challenging that I often want to do extra work.
- 1150 DATA The fringe benefits of my job are satisfactory.
- 1160 DATA The amount of pressure at work is adequately stimulating and maximizes my work output.
- 1170 DATA My job provides me with an adequate amount of free time to pursue outside activities.
- 1180 DATA I have a sufficient amount of contact with other people through my work.
- 1190 DATA I often get to exchange ideas with other people through my work.
- 1200 DATA My supervisors let me know that they appreciate my work.
- 1210 DATA I meet an ample number and variety of people through work-related activities.
- 1220 DATA I feel that my social skills are constantly improving as a result of my work-related activities.
- 1230 DATA I am making adequate advancement through my career.
- 1240 DATA My career will continue to provide ample job flexibility in the future.
- 1250 DATA I will be able to reach my goals through my present career.
- 1260 DATA My career will continue to provide stimuilating challenges in the future.
- 1270 DATA My job is in a growing field.
- ə